Code arduino ESP32 pour alimenter MQTT

Voici un code qui tourne et permet d'alimenter un broker MQTT.

ATTENTION : mettre à jour le user/pwd du broker MQTT

#include <WiFi.h>
#include <PubSubClient.h>
#include <DHT.h>
#include <Adafruit_Sensor.h>

// ----- Réseau -----
const char* ssid = "2.4GHz-MEMOIRE-VIVE";
const char* password = "memoirevive79";
const char* mqtt_server = "192.168.1.249";

// ---- Capteur ----
#define DHTPIN 15   // GPIO utilisé pour DHT22
#define DHTTYPE DHT22
DHT dht(DHTPIN, DHTTYPE);

// ----- MQTT -----
WiFiClient espClient;
PubSubClient client(espClient);
unsigned long lastMsg = 0;
#define MSG_BUFFER_SIZE 50
char msg[MSG_BUFFER_SIZE];
int value = 0;

// ----- Connexion WiFi -----
void setup_wifi() {
  delay(10);
  Serial.println();
  Serial.print("Connecting to ");
  Serial.println(ssid);

  WiFi.mode(WIFI_STA);
  WiFi.begin(ssid, password);

  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }

  randomSeed(micros());

  Serial.println("");
  Serial.println("WiFi connected");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());
}

// ----- Callback MQTT -----
void callback(char* topic, byte* payload, unsigned int length) {
  Serial.print("Message arrived [");
  Serial.print(topic);
  Serial.print("] ");
  for (int i = 0; i < length; i++) {
    Serial.print((char)payload[i]);
  }
  Serial.println();
}

// ----- Reconnexion MQTT -----
void reconnect() {
  while (!client.connected()) {
    Serial.print("Attempting MQTT connection...");
    String clientId = "ESP32Client-";
    clientId += String(random(0xffff), HEX);

    if (client.connect(clientId.c_str(), "telegraf", "dbraux")) {
      // --- Publication MQTT Discovery pour Home Assistant ---
      // Température
      client.publish("homeassistant/sensor/esp32_temperature/config",
                 "{\"name\": \"ESP32 Temperature\", \"state_topic\": \"sensors/esp32/temperature\", \"unit_of_measurement\": \"°C\", \"device_class\": \"temperature\"}",
                 true);  // retained = true

      // Humidité
      client.publish("homeassistant/sensor/esp32_humidity/config",
                 "{\"name\": \"ESP32 Humidity\", \"state_topic\": \"sensors/esp32/humidity\", \"unit_of_measurement\": \"%\", \"device_class\": \"humidity\"}",
                 true);  // retained = true
      Serial.println("connected");
      client.subscribe("inTopic");
    } else {
      Serial.print("failed, rc=");
      Serial.print(client.state());
      Serial.println(" try again in 5 seconds");
      delay(5000);
    }
  }
}

// ----- Setup -----
void setup() {
  pinMode(2, OUTPUT);     
  digitalWrite(2, HIGH); // LED ON
  Serial.begin(115200);
  setup_wifi();
  client.setServer(mqtt_server, 1883);
  client.setCallback(callback);
  dht.begin();
}

// ----- Loop -----
void loop() {
  if (!client.connected()) {
    reconnect();
  }
  client.loop();

  unsigned long now = millis();
  if (now - lastMsg > 30000) {
    lastMsg = now;
    ++value;

    float temperature = dht.readTemperature();
    float humidity = dht.readHumidity();

    if (!isnan(temperature) && !isnan(humidity)) {
      char tempStr[8];
      char humStr[8];
      dtostrf(temperature, 1, 2, tempStr);
      dtostrf(humidity, 1, 2, humStr);

      Serial.print("Temp: ");
      Serial.print(tempStr);
      Serial.print(" °C, Hum: ");
      Serial.print(humStr);
      Serial.println(" %");

      // Allumer la LED juste avant l'envoi
      digitalWrite(2, HIGH); // LED ON

      client.publish("sensors/esp32/temperature", tempStr);
      client.publish("sensors/esp32/humidity", humStr);

      // Éteindre la LED juste après l'envoi
      delay(200);
      digitalWrite(2, LOW); // LED OFF      
    } else {
      Serial.println("Erreur lecture DHT22");
    }
  }
}